// MODELE CRR
  
function [Y] = prix_en_zero(N,K,r,a,b,x)

p = (b-r)/(b-a);
xi=x * (1+a)^N*((1+b)/(1+a))^(0:N);
Prix=max(xi-K,0);
p1 = p/(1+r);
p2 = (1-p)/(1+r);

for j = 1:N
  Prix=p1*Prix(1:(N-j+1))+p2*Prix(2:(N-j+2));  
end

Y = Prix;
endfunction

function[Y]= prix_temps_n(n,N,K,r,a,b,x)
   Y = prix_en_zero(N-n,K,r,a,b,x);
 endfunction
 
function[Y]= couverture(n,N,K,r,a,b,x) 
    Y = (prix_en_zero(N-n,K,r,a,b,x*(1+b))-prix_en_zero(N-n,K,r,a,b,x*(1+a)))/(x*(b-a));
  endfunction
  
  // MODELE BLACK SCHOLES
  
function[Y]=d1(t,T,K,R,sigma,x)
   //Y=(log(x/K)+(r+(sigma^2)/2)*(T-t))/(sigma*sqrt(T-t));
  if t==T
   if x>K then Y=9999999;else Y=-9999999;end
  else
   Y=(log(x/K)+(R+(sigma^2)/2)*(T-t))/(sigma*sqrt(T-t));
  end
 endfunction

function [y]=C_bs(t,S0,K,T,R,vol_mod)
  d_1=d1(t,T,K,R,vol_mod,S0);
  d_2=d_1 - vol_mod*sqrt(T-t);
  y=S0*cdfnor("PQ",d_1,0,1)-K*exp(-R*(T-t))*cdfnor("PQ",d_2,0,1);
endfunction

function [y]=delta_bs(t,S0,K,T,R,vol_mod)
  d_1=d1(t,T,K,R,vol_mod,S0);
  y=cdfnor("PQ",d_1,0,1);
endfunction