///withoutPrompt 
function [XX,T]=simul_car(TT,X)
  Tt=TT; // remaining time instances
  XX=[];T=[]; // intialization of outputs
  tc=0;  //current time
  delt=1d-3; // time interval without root
  while 1
    t=tc+delt; 
    It=find(Tt<t); // find indices of output points 
    if It==[] then
      xt=ode(X,tc,t,car);  // no root simulation
    else
      Xx=ode(X,tc,Tt(It),car); 
      T=[T,Tt(It)];XX=[XX,Xx];xt=Xx(:,$);Tt(It)=[];
    end
    [Xx,rd]=ode('root',xt,t,Tt,car,2,carg);
    if rd==[] then // no root found, update outputs
      XX=[XX,Xx];T=[T,Tt];break;
    end 
    tc=rd(1);  // root found at time tc
    if size(rd,'*')==3 then // two roots crossed
      ST0=1-ST0;ST1=1-ST1; // change both states
    else
      if rd(2)==1 then ST0=1-ST0;end  // rear wheel
      if rd(2)==2 then ST1=1-ST1;end  // front wheel
    end
    T=[T,Tt(find(Tt<rd(1))),rd(1)];XX=[XX,Xx];X=Xx(:,$);
    // update outputs, time of zero-crossing added to TT
    Tt=Tt(find(Tt>rd(1))); // update remaining time instances
  end
endfunction ///\withPrompt{}